The "configs" variable of "executable", "shared_library", ... targets is treated specially and initialised with default global values.

This means that when setting the variable in a target user has to use "configs += [ ... ]" and also means that it is difficult to write a template wrapping one of those targets while still allowing the user to expand "configs".

Let's use the following simple shared_library and try to write a template that will wrap it (an example of such a template is mac_framework in //build/config/mac/rules.gni):

config("config") {
  # Some configuration required for foo.
}

shared_library("foo") {
  sources = foo_sources
  configs += [ ":config" ]
}

The obvious way to write such a template as either user get an error during generation or the configs used by the target lose the defaults.

template("shared_library_tmpl_1") {
  shared_library(target_name) {
    forward_variables_from(invoker, "*")
  }
}

shared_library_tmpl_1("foo_tmpl_1") {
  sources = foo_sources
  configs += [ ":config" ]
}

shared_library_tmpl_1("foo_tmpl_2") {
  sources = foo_sources
  configs = [ ":config" ]
}

The "foo_tmpl_1" causes the following error while running "gn gen":

$ gn gen out/gn
ERROR at //foo/BUILD.gn:29:3: Undefined variable for +=.
  configs += [ ":config" ]
  ^------
I don't have something with this name in scope now.

while "foo_tmpl_2" overrides the default configs and causes foo and foo_tmpl_2 resulting in  probable compilation failure.

$ gn desc out/gn //foo:foo configs
  //build/config:feature_flags
  //build/config/compiler:compiler
  //build/config/compiler:clang_stackrealign
  //build/config/compiler:compiler_arm_fpu
  //build/config/compiler:chromium_code
  //build/config/compiler:default_include_dirs
  //build/config/compiler:default_optimization
  //build/config/compiler:default_symbols
  //build/config/compiler:no_rtti
  //build/config/compiler:runtime_library
  //build/config/sanitizers:default_sanitizer_flags
  //build/config/sanitizers:default_sanitizer_coverage_flags
  //build/config/gcc:no_exceptions
  //build/config/gcc:symbol_visibility_hidden
  //build/config/clang:find_bad_constructs
  //build/config/clang:extra_warnings
  //build/config:debug
  //build/config:default_libs
  //build/config:shared_library_config
  //ios/web:config
$ gn desc out/gn //foo:foo_tmpl_2 configs
  //ios/web:config

The template needs to be written this way to work:

template("shared_library_tmpl_2") {
  shared_library(target_name) {
    forward_variables_from(invoker, "*", ["configs"])
    if (defined(invoker.configs)) {
      configs += invoker.configs
    }
  }
}

shared_library_tmpl_2("foo_tmpl_3") {
  sources = foo_sources
  configs = [ ":config" ]
}

Then we have the correct list of configs for foo_tmpl_3. However, I argue that this is difficult to write this template correctly due to how configs is treated.